//N. Busch 16.10.2006
Let(
[$Namekurz = Trim( d_AutorNachname_t & " " & Left( d_AutorVorname_t ; 1) ) ;
$NameHRSGkurz = Trim( DTitel.Titel.Sammelband::d_AutorNachname_t & " " & Left( DTitel.Titel.Sammelband::d_AutorVorname_t ; 1) ) ;
$HRSG = case( not isempty(DTitel.Titel.Sammelband::d_Herausgeber_t) ; DTitel.Titel.Sammelband::d_Herausgeber_t ; "(Hg.)")
]
;
Case(
IsValid( DTitel.Periodikum::_pk_GUID.Periodikum );
// Zitform für Artikel
Trim(
$Namekurz &
Case( not IsEmpty( d_CoAutoren_t ) ; ", " & d_CoAutoren_t ) &
Case(not IsEmpty(d_DatumJahr_t) ; " (" & d_DatumJahr_t & ")") &
" " & d_Titel_t & case( patterncount( ".!?" ; right(d_titel_t ; 1)) = 0; ". " ; " ") &
DTitel.Periodikum::d_Titel_t &
Case( not IsEmpty( d_AusgabeVol_t ); " " & d_AusgabeVol_t ) &
Case( not isempty( d_ausgabeVol_t) and not isempty( d_ausgabeNr_t) ; "/") &
Case( not IsEmpty( d_AusgabeNr_t ); " " & d_AusgabeNr_t ) &
Case( not IsEmpty( d_AusgabeSeite_t) ; ": " & case( filter(Trim( d_AusgabeSeite_t ) ; "-/0123456789") = trim( d_AusgabeSeite_t ) ;"S ") & Trim( d_AusgabeSeite_t ) )
) // End trim
;
IsValid( DTitel.Titel.Sammelband::_pk_GUID.Titel );
// Zitform für Aufsätze
Trim(
$Namekurz &
Case( not IsEmpty( d_CoAutoren_t ) ; ", " & d_CoAutoren_t ) &
Case(not IsEmpty(DTitel.Titel.Sammelband::d_DatumJahr_t) ; " (" & DTitel.Titel.Sammelband::d_DatumJahr_t & ")") &
" " & d_Titel_t & case( patterncount( ".!?" ; right(d_titel_t ; 1)) = 0; ". " ; " ") & "In: " &
$NameHRSGkurz &
" " & $HRSG & " " &
DTitel.Titel.Sammelband::d_Titel_t &
Case( not IsEmpty( DTitel.Titel.Sammelband::d_verlag_t ); ", " & DTitel.Titel.Sammelband::d_verlag_t) &
Case( not IsEmpty( DTitel.Titel.Sammelband::d_ort_t ) ; ", " & DTitel.Titel.Sammelband::d_ort_t ) &
Case( not IsEmpty( d_AusgabeSeite_t) ; ", " & case( filter(Trim( d_AusgabeSeite_t ) ; "-/0123456789") = trim( d_AusgabeSeite_t ) ;"S ") & Trim( d_AusgabeSeite_t ) )
) // End trim
;
// Zitform für Monographien
Trim(
$Namekurz &
Case( not IsEmpty( d_CoAutoren_t ) ; ", " & d_CoAutoren_t ) &
Case( not IsEmpty( d_herausgeber_t ) ; " (" & d_herausgeber_t & ")" ) &
Case(not IsEmpty(d_DatumJahr_t) ; " (" & d_DatumJahr_t & ")") &
" " & d_Titel_t & case( patterncount( ".!?" ; right(d_titel_t ; 1)) = 0; ". " ; " ") &
Case( not IsEmpty( d_verlag_t ); d_verlag_t ) &
Case( not IsEmpty( d_Ort_t ) and not IsEmpty( d_Verlag_t ) ; ", ") &
Case( not IsEmpty( d_Ort_t ) ; d_Ort_t )
) // End trim
) //End Case
& DGlobals::v_ZitformSchlusszeichen
) // End let