/* basiert auf Suhrkamp VN von N. Busch 18.04.2009; N. Linder 17.5.2009 */
Let(
[$Periodikum =
Case( DGlobals::d_SigleBenutzen_n = 1 and not IsEmpty( DTitel.Periodikum::d_Sigle_t );
DTitel.Periodikum::d_Sigle_t;
DTitel.Periodikum::d_Titel_t );
$HerausgeberStatus =
Case( IsEmpty( d_HerausgeberName_t) and d_Herausgeber_n <> 1 ; 0;
IsEmpty( d_HerausgeberName_t) and d_Herausgeber_n = 1 ; 1 ;
not IsEmpty( d_HerausgeberName_t) and IsEmpty(d_AutorNachname_t); 2;
not IsEmpty( d_HerausgeberName_t) and not IsEmpty(d_AutorNachname_t); 3);
$AutorPerson =
Trim(
TextStyleAdd( d_AutorVorname_t ; SmallCaps ) & " " & TextStyleAdd( d_AutorNachname_t ; SmallCaps ) & TextStyleAdd( xCalc_Pseudonym_ctu ; SmallCaps ) ) ;
$Coautoren =
Trim(Case(
not IsEmpty( xCalc_NamenCoautorenVN_ctu) ;
DGlobals::d_CoAutorTrenner_t & TextStyleAdd( xCalc_NamenCoautorenVN_ctu ; SmallCaps) ;
not IsEmpty( d_CoAutoren_t ) ;
"/" & TextStyleAdd( d_CoAutoren_t ; SmallCaps )
)) ;
$CoautorenSB =
Trim(Case(
not IsEmpty( DTitel.Titel.Sammelband::xCalc_NamenCoautorenVN_ctu) ;
TextStyleAdd( DGlobals::d_CoAutorTrenner_t ; SmallCaps ) & DTitel.Titel.Sammelband::xCalc_NamenCoautorenVN_ctu ;
not IsEmpty( DTitel.Titel.Sammelband::d_CoAutoren_t ) ;
"/" & TextStyleAdd( DTitel.Titel.Sammelband::d_CoAutoren_t ; SmallCaps)
));
$Autor =
Case(
$Herausgeberstatus = 0;
$Autorperson &
$Coautoren;
$Herausgeberstatus = 1;
$Autorperson &
$Coautoren &
" (" & DGlobals::d_HerausgeberKürzel_t & ")" ;
$Herausgeberstatus = 2;
TextStyleAdd( d_HerausgeberName_t ; SmallCaps ) & " (" & DGlobals::d_HerausgeberKürzel_t & ")" ;
$Herausgeberstatus = 3;
$Autorperson &
$Coautoren
;
) // end case
]
;
Case(
d_Datentyp2_t = "Artikel";
// Zitform für Artikel
Trim(
$Autor &
", " & d_Titel_t & ", in: " &
$Periodikum &
Case(
not IsEmpty( d_AusgabeVol_t ) ;
" " & d_AusgabeVol_t &
Case( not IsEmpty( d_Datierung_t ) ; " " & "(" & d_Datierung_t & ")" ) ;
Case(not IsEmpty(d_Datierung_t) ;
", " & d_Datierung_t )
) // End Case
&
Case( not IsEmpty( d_AusgabeNr_t ); ", Nr. " & d_AusgabeNr_t ) &
Case( not IsEmpty( d_AusgabeSeite_t) ; ", S. " & d_AusgabeSeite_t )
) // End trim
;
d_Datentyp2_t = "Aufsatz";
// Zitform für Aufsätze
Trim(
$Autor &
", " & d_Titel_t & ", in: " &
Case(
DTitel::_fk_Autor_ct <> DTitel.Titel.Sammelband::_fk_Autor_ct;
Trim( DTitel.Titel.Sammelband::d_AutorVorname_t & " " & DTitel.Titel.Sammelband::d_AutorNachname_t) & $CoautorenSB;
not IsEmpty( DTitel::xCalc_NamenCoautorenVN_ctu) and DTitel::xCalc_NamenCoautorenVN_ctu =
DTitel.Titel.Sammelband::xCalc_NamenCoautorenVN_ctu ;
"dies." ;
DTitel.Autor::d_Geschlecht_t = "f";
"dies." & $CoautorenSB;
"ders." & $CoautorenSB ) &
Case( DTitel.Titel.Sammelband::d_Herausgeber_n = 1 ; " (" & DGlobals::d_HerausgeberKürzel_t & "), "; ", " ) &
DTitel.Titel.Sammelband::d_Titel_t & ", " &
Case( not IsEmpty( DTitel.Titel.Sammelband::d_Ort_t ); DTitel.Titel.Sammelband::d_Ort_t ) &
Case( not IsEmpty( DTitel.Titel.Sammelband::d_Datierung_t ) ; " " & DTitel.Titel.Sammelband::d_Datierung_t ) &
Case( not IsEmpty( d_AusgabeSeite_t ) ; ", S. " & d_AusgabeSeite_t )&
Case( not IsEmpty( DTitel.Titel.Sammelband::_fk_sammelband_t );
/* Ein Ausatz in Sammelband als Teil einer Werkausgabe */
" [" & Trim( DTitel.Titel.SB.Werkausgabe::d_Kurztitel_t & " " & DTitel.Titel.Sammelband::d_AusgabeVol_t &
Case(
not IsEmpty( DTitel.Titel.Sammelband::d_AusgabeVol_t ) and not IsEmpty( DTitel.Titel.Sammelband::d_AusgabeNr_t) ;
"/") & DTitel.Titel.Sammelband::d_AusgabeNr_t
)
& "]"
) //end case
) // End trim
;
d_Datentyp2_t = "Vortrag";
// Zitform für Vorträge
Trim(
$Autor &
", " & Quote( d_Titel_t ) & ", Vortrag, " &
"" & Quote( DTitel.Titel.Sammelband::d_Titel_t ) & ", " &
Case( not IsEmpty( DTitel.Titel.Sammelband::d_Ort_t ); DTitel.Titel.Sammelband::d_Ort_t ) &
Case( not IsEmpty( DTitel.Titel.Sammelband::d_Datierung_t ) ; " " & DTitel.Titel.Sammelband::d_Datierung_t )
) // End trim
;
d_Datentyp2_t = "Tagung";
// Zitform für Tagungen
Trim(
"Tagung " &
" " & Quote( d_Titel_t ) & "" &
Case( not IsEmpty( d_Körperschaft_t ); ", " & d_Körperschaft_t ) &
Case( not IsEmpty( d_Ort_t ) ; ", " & d_Ort_t ) &
Case( not IsEmpty( d_Datierung_t ) ; ", " & d_Datierung_t )
) // End trim
;
// Zitform für Monographien und den Rest
Trim(
$Autor &
", " & d_Titel_t &
Case( $HerausgeberStatus = 3 ; "Hg. v. " & d_HerausgeberName_t & ", " ) &
Case( not IsEmpty( d_Auflage_t ) ; " " & d_Auflage_t & ". Aufl. " ) &
", " & Case( not IsEmpty( d_Ort_t ); d_Ort_t ) &
Case( not IsEmpty( d_Datierung_t ) ; " " & d_Datierung_t ) &
Case( not IsEmpty( d_BibliogrZusätze_t ) ; " (" & d_BibliogrZusätze_t & ")") &
Case( not IsEmpty( DTitel.Titel.Sammelband::_pk_GUID );
/* Eine Monographie mit Verknüpfung zu einem Sammelband ist Teil einer Werkausgabe */
" [" & Trim( DTitel.Titel.Sammelband::d_Kurztitel_t &
Case( not isempty( d_AusgabeVol_t ) ;", Bd. " & d_AusgabeVol_t ) &
Case(not IsEmpty( d_AusgabeVol_t ) and not IsEmpty(d_AusgabeNr_t) ; " Nr. ";
not isempty(d_AusgabeNr_t) ; ", Nr. ") &
d_AusgabeNr_t)
& "]"
) //end case
) // End trim
) //End Case
& DGlobals::v_ZitFormSchlusszeichen
)